refactor: complete overhaul

Complete overhaul of repo structure based on nvix.

See https://github.com/niksingh710/nvix

Signed-off-by: Lander Van den Bulcke <landervandenbulcke@gmail.com>

modules/flake/default.nix

@@ -0,0 +1,23 @@
+{ inputs, self, ... }:
+{
+  debug = true;
+
+  imports = [ ./devshell.nix ];
+
+  perSystem =
+    { lib, system, ... }:
+    {
+      _module.args = {
+        flake = { inherit inputs self; };
+        pkgs = import inputs.nixpkgs {
+          inherit system;
+          overlays = lib.attrValues self.overlays;
+          config.allowUnfree = true;
+        };
+      };
+
+      imports = [
+        (self + /packages)
+      ];
+    };
+}

modules/flake/devshell.nix

@@ -0,0 +1,32 @@
+{ inputs, ... }:
+{
+  imports = [
+    (inputs.git-hooks + /flake-module.nix)
+  ];
+
+  perSystem =
+    { config, pkgs, ... }:
+    {
+      devShells.default = pkgs.mkShell rec {
+        name = "nixvim";
+        meta.description = "Dev environment for nixvim configuration";
+
+        inputsFrom = [ config.pre-commit.devShell ];
+
+        packages = with pkgs; [
+          nil
+          nix-output-monitor
+          nixfmt-rfc-style
+        ];
+
+        shellHook = ''
+          echo 1>&2 "🐼: $(id -un) | 🧬: $(nix eval --raw --impure --expr 'builtins.currentSystem') | 🐧: $(uname -r) "
+          echo 1>&2 "Ready to work on ${name}!"
+        '';
+      };
+
+      pre-commit.settings = {
+        hooks.nixfmt-rfc-style.enable = true;
+      };
+    };
+}